窩窩論壇上我們每天都會發布excel練習題給窩友們學習，在出題時，經常會遇到模擬隨機生成姓名和數據。

　　數字可以使用rand、RANDBETWEEN函數來隨機生成。可是姓名如何弄呢，本文介紹使用VBA自動隨機生成姓名。

　　具體的隨機生成姓名如下介紹：

　　第一步，新建一個excel工作薄

　　這個工作薄里面包含兩個工作表，分別是“姓名數據”和“生成隨機姓名”。

　　其中的“姓名數據”工作表，有三列數據：百家姓、男子名、女子名，是我們之前已經輸入好了的。

　　第二步，切換到“生成隨機姓名”工作表，單擊“生成隨機姓名”按鈕，excel會出現一個輸入框，提示我們輸入要生成的人名數。比如我們輸入100，單擊“確定”，此工作表A列就會隨機生成姓名100個。

　　下面提供隨機生成姓名的VBA代碼，使用方法是按下ALT+F11組合鍵，打開VBE編輯器，插入——模塊，復制下面的代碼，然后為了操作方便，我們在“生成隨機姓名”工作表中插入了一個按鈕，將這段代碼指定給按鈕。

Sub 隨機生成姓名()
Dim Arr, Arr2, Arr3, I%, N&, S As BooLEAN, Str$, Dic, A&, B&
N = Val(InputBox("請輸入要生成的人名數："))     '輸入要生成的隨機人名數量
If N = 0 Then Exit Sub      '如果未輸入或點了取消則退出程序
Set Dic = CreateObject("scripting.dictionary")  '創建字典項目，用于清除生成的重復的人名
With Sheet1     '從sheet1中讀取數據并隨機生成姓名
    Arr = .Range(.[a2], .Cells(.Rows.Count, 1).End(3))  '讀取百家姓放入數組
    Arr2 = .Range(.[b2], .Cells(.Rows.Count, 2).End(3))    '讀取男子名常用字放入數組
    Arr3 = .Range(.[c2], .Cells(.Rows.Count, 3).End(3))     '讀取女子名常用字放入數組
    Do  '循環執行
        Str = ""       '先清空用于存儲生成的名字的變量
        S = Rnd > 0.5   '用取得的隨機數來判斷生成男子名還是女子名
        I = 2 + IIf(Rnd > 0.8, 0, 1)    '用隨機數確定生成的名字的字符數（80%的幾率為三個字）
        If S Then   '如果是男子名，則
            A = Int(Rnd * (UBound(Arr) - 2)) + 2    '取得姓對應的數組下標
            B = Int(Rnd * (UBound(Arr2) - 2)) + 2   '取得名字的對應下數組下標
            Str = Arr(A, 1) & Arr2(B, 1)    '串接名字
            If I > 2 Then   '如果名字的字符數大于2，則再得一次名字的字符下標并串接給字符串變量
                B = Int(Rnd * (UBound(Arr2) - 2)) + 2
                Str = Str & Arr2(B, 1)
            End If
        Else    '如果是女子名，則取對應的女子名數組內容，處理方式同上
            A = Int(Rnd * (UBound(Arr) - 2)) + 2
            B = Int(Rnd * (UBound(Arr3) - 2)) + 2
            Str = Arr(A, 1) & Arr3(B, 1)
            If I > 2 Then
                B = Int(Rnd * (UBound(Arr3) - 2)) + 2
                Str = Str & Arr3(B, 1)
            End If
        End If
        Dic(Str) = ""   '將隨機姓名放入字典中
    Loop Until Dic.Count = N    '如果字典項目數量達到輸入的數值則跳出循環
End With
With Sheet2     '將結果寫入sheet2中
    .Cells.Clear    '清空原有內容
    If Dic.Count > 65536 Then   '防止數量太多時無法轉置及數據超出單元格最大行號的情況
        Arr = Dic.keys
        For N = LBound(Arr) To UBound(Arr)
            Cells((N Mod 65536) + 1, N \ 65536 + 1) = Arr(N)
        Next N
    Else    '數量少時直接轉置
        .[a1].Resize(Dic.Count, 1) = Application.Transpose(Dic.keys)    '轉置字典的keys值
    End If
End With
Set Dic = Nothing   '清空字典項目
End Sub

核心關注：拓步ERP系統平臺是覆蓋了眾多的業務領域、行業應用，蘊涵了豐富的ERP管理思想，集成了ERP軟件業務管理理念，功能涉及供應鏈、成本、制造、CRM、HR等眾多業務領域的管理，全面涵蓋了企業關注ERP管理系統的核心領域，是眾多中小企業信息化建設首選的ERP管理軟件信賴品牌。

轉載請注明出處：拓步ERP資訊網http://www.guhuozai8.cn/

本文標題：利用excel中vba代碼隨機生成姓名列表的方法

本文網址：http://www.guhuozai8.cn/html/support/11139213451.html